Diagnostic Programs
BASIC Code Listings
MONITOR QUALITY TESTS

8300 REM ==== ====
8305 REM ==== MONITOR QUALITY TESTS ====
8306 C1$ = CHR$(219): C10$ = C1$ + C1$ + C1$ + C1$ + C1$ + C1$ + C1$ + C1$ + C1$ + C1$
8307 C2$ = CHR$(218): C3$ = CHR$(196): C4$ = CHR$(191): C5$ = CHR$(179)
8308 C6$ = CHR$(192): C7$ = CHR$(217): C8$ = CHR$(194): C9$ = CHR$(193)
8309 C11$ = CHR$(195): C12$ = CHR$(197): C13$ = CHR$(180)
8310 SCREEN 0, 1: COLOR 7, 0: CLS
8315 L% = 23: REM Screen height minus 1
8320 PRINT "Monitor Quality Tests": PRINT
8322 PRINT "1 - Color purity test"
8324 PRINT "2 - Convergence test"
8326 PRINT "3 - EHT (extra high tension) Regulation test"
8328 PRINT "9 - Exit": PRINT
8330 K$ = INKEY$: IF K$ = "" THEN 8330
8331 IF K$ = "1" THEN GOSUB 8340
8332 IF K$ = "2" THEN GOSUB 8350
8333 IF K$ = "3" THEN GOSUB 8400
8334 IF K$ = "9" THEN END
8335 GOTO 8310
8340 REM ==== Color purity test ====
8342 COLOR 15, 0: CLS
8344 FOR I% = 1 TO 2000: PRINT C1$; : NEXT I%
8346 COLOR 7, 0: LOCATE L%, 57: PRINT "Press any key to exit"
8348 K$ = INKEY$: IF K$ = "" THEN 8348
8349 RETURN
8350 REM ==== Convergence test ====
8352 COLOR 15, 0: CLS
8354 PRINT C2$; : FOR I% = 1 TO 78: PRINT C8$; : NEXT I%: PRINT C4$;
8356 FOR J% = 2 TO L%
8358 PRINT C11$; : FOR I% = 1 TO 78: PRINT C12$; : NEXT I%: PRINT C13$;
8360 NEXT J%
8362 PRINT C6$; : FOR I% = 1 TO 78: PRINT C9$; : NEXT I%: PRINT C7$;
8364 LOCATE L%, 57: PRINT "Press any key to exit"
8366 K$ = INKEY$: IF K$ = "" THEN 8366
8368 RETURN
8400 REM ==== Test EHT (extra high tension) Regulation ====
8410 CLS
8420 PRINT C2$; : FOR I% = 1 TO 78: PRINT C3$; : NEXT I%: PRINT C4$;
8422 FOR J% = 2 TO L%
8424 PRINT C5$; : FOR I% = 1 TO 78: PRINT " "; : NEXT I%: PRINT C5$;
8426 NEXT J%
8428 PRINT C6$; : FOR I% = 1 TO 78: PRINT C3$; : NEXT I%: PRINT C7$;
8430 COLOR 31, 0
8432 FOR J% = 3 TO L% - 2
8434 LOCATE J%, 6
8436 FOR K% = 1 TO 7: PRINT C10$; : NEXT K%
8438 NEXT J%
8440 COLOR 7, 0
8445 LOCATE L%, 57: PRINT "Press any key to exit"
8448 K$ = INKEY$: IF K$ = "" THEN 8448
8450 CLS
8455 RETURN
8490 END